SXML
====

SXML is a native representation of XML in terms of standard Scheme data types: lists, symbols, and strings.  For example, the simple XML fragment:

     <parrot type="African Grey"><name>Alfie</name></parrot>

may be represented with the following SXML:

     (parrot (@ (type "African Grey")) (name "Alfie"))

SXML is very general, and is capable of representing all of XML. Formally, this means that SXML is a conforming implementation of the http://www.w3.org/TR/xml-infoset/ (XML Information Set) standard.

Guile includes several facilities for working with XML and SXML: parsers, serializers, and transformers.

SXML Overview
-------------

(This section needs to be written; volunteers welcome.)

Reading and Writing XML
-----------------------

The (sxml simple) module presents a basic interface for parsing XML from a port into the Scheme SXML format, and for serializing it back to text.

     (use-modules (sxml simple))

 -- Scheme Procedure: xml->sxml [string-or-port] [#:namespaces='()]
     [#:declare-namespaces?=#t] [#:trim-whitespace?=#f]
     [#:entities='()] [#:default-entity-handler=#f]
     [#:doctype-handler=#f]
     Use SSAX to parse an XML document into SXML. Takes one optional argument, STRING-OR-PORT, which defaults to the current input port.  Returns the resulting SXML document.  If STRING-OR-PORT is a port, it will be left pointing at the next available character in the port.

As is normal in SXML, XML elements parse as tagged lists.  Attributes, if any, are placed after the tag, within an @ element.  The root of the resulting XML will be contained in a special tag, *TOP*. This tag will contain the root element of the XML, but also any prior processing instructions.

     (xml->sxml "<foo/>")
     => (*TOP* (foo))
     (xml->sxml "<foo>text</foo>")
     => (*TOP* (foo "text"))
     (xml->sxml "<foo kind=\"bar\">text</foo>")
     => (*TOP* (foo (@ (kind "bar")) "text"))
     (xml->sxml "<?xml version=\"1.0\"?><foo/>")
     => (*TOP* (*PI* xml "version=\"1.0\"") (foo))

All namespaces in the XML document must be declared, via xmlns attributes.  SXML elements built from non-default namespaces will have their tags prefixed with their URI.  Users can specify custom prefixes for certain namespaces with the #:namespaces keyword argument to xml->sxml.

     (xml->sxml "<foo xmlns=\"http://example.org/ns1\">text</foo>")
     => (*TOP* (http://example.org/ns1:foo "text"))
     (xml->sxml "<foo xmlns=\"http://example.org/ns1\">text</foo>"
                #:namespaces '((ns1 . "http://example.org/ns1")))
     => (*TOP* (ns1:foo "text"))
     (xml->sxml "<foo xmlns:bar=\"http://example.org/ns2\"><bar:baz/></foo>"
                #:namespaces '((ns2 . "http://example.org/ns2")))
     => (*TOP* (foo (ns2:baz)))

By default, namespaces passed to xml->sxml are treated as if they were declared on the root element.  Passing a false #:declare-namespaces? argument will disable this behavior, requiring in-document declarations of namespaces before use..

     (xml->sxml "<foo><ns2:baz/></foo>"
                #:namespaces '((ns2 . "http://example.org/ns2")))
     => (*TOP* (foo (ns2:baz)))
     (xml->sxml "<foo><ns2:baz/></foo>"
                #:namespaces '((ns2 . "http://example.org/ns2"))
                #:declare-namespaces? #f)
     => error: undeclared namespace: `bar'

By default, all whitespace in XML is significant.  Passing the #:trim-whitespace? keyword argument to xml->sxml will trim whitespace in front, behind and between elements, treating it as ``unsignificant''.  Whitespace in text fragments is left alone.

     (xml->sxml "<foo>\n<bar> Alfie the parrot! </bar>\n</foo>")
     => (*TOP* (foo "\n" (bar " Alfie the parrot! ") "\n"))
     (xml->sxml "<foo>\n<bar> Alfie the parrot! </bar>\n</foo>"
                #:trim-whitespace? #t)
     => (*TOP* (foo (bar " Alfie the parrot! ")))

Parsed entities may be declared with the #:entities keyword argument, or handled with the #:default-entity-handler.  By default, only the standard &lt;, &gt;, &amp;, &apos; and &quot; entities are defined, as well as the &#N; and &#xN; (decimal and hexadecimal) numeric character entities.

     (xml->sxml "<foo>&amp;</foo>")
     => (*TOP* (foo "&"))
     (xml->sxml "<foo>&nbsp;</foo>")
     => error: undefined entity: nbsp
     (xml->sxml "<foo>&#xA0;</foo>")
     => (*TOP* (foo "\xa0"))
     (xml->sxml "<foo>&nbsp;</foo>"
                #:entities '((nbsp . "\xa0")))
     => (*TOP* (foo "\xa0"))
     (xml->sxml "<foo>&nbsp; &foo;</foo>"
                #:default-entity-handler
                (lambda (port name)
                  (case name
                    ((nbsp) "\xa0")
                    (else
                     (format (current-warning-port)
                             "~a:~a:~a: undefined entitity: ~a\n"
                             (or (port-filename port) "<unknown file>")
                             (port-line port) (port-column port)
                             name)
                     (symbol->string name)))))
     -| <unknown file>:0:17: undefined entitity: foo
     => (*TOP* (foo "\xa0 foo"))

By default, xml->sxml skips over the <!DOCTYPE> declaration, if any.  This behavior can be overridden with the #:doctype-handler argument, which should be a procedure of three arguments: the docname (a symbol), systemid (a string), and the internal doctype subset (as a string or #f if not present).

The handler should return keyword arguments as multiple values, as if it were calling its continuation with keyword arguments.  The continuation accepts the #:entities and #:namespaces keyword arguments, in the same format that xml->sxml itself takes.  These entities and namespaces will be prepended to those given to the xml->sxml invocation.

     (define (handle-foo docname systemid internal-subset)
       (case docname
         ((foo)
          (values #:entities '((greets . "<i>Hello, world!</i>"))))
         (else
          (values))))

     (xml->sxml "<!DOCTYPE foo><p>&greets;</p>"
                #:doctype-handler handle-foo)
     => (*TOP* (p (i "Hello, world!")))

If the document has no doctype declaration, the DOCTYPE-HANDLER is invoked with #f for the three arguments.

In the future, the continuation may accept other keyword arguments, for example to validate the parsed SXML against the doctype.

 -- Scheme Procedure: sxml->xml tree [port]
     Serialize the SXML tree TREE as XML. The output will be written to the current output port, unless the optional argument PORT is present.

 -- Scheme Procedure: sxml->string sxml
     Detag an sxml tree SXML into a string. Does not perform any formatting.

SSAX: A Functional XML Parsing Toolkit
--------------------------------------

Guile's XML parser is based on Oleg Kiselyov's powerful XML parsing toolkit, SSAX.

History
.......

Back in the 1990s, when the world was young again and XML was the solution to all of its problems, there were basically two kinds of XML parsers out there: DOM parsers and SAX parsers.

A DOM parser reads through an entire XML document, building up a tree of ``DOM objects'' representing the document structure.  They are very easy to use, but sometimes you don't actually want all of the information in a document; building an object tree is not necessary if all you want to do is to count word frequencies in a document, for example.

SAX parsers were created to give the programmer more control on the parsing process.  A programmer gives the SAX parser a number of ``callbacks'': functions that will be called on various features of the XML stream as they are encountered.  SAX parsers are more efficient, but much harder to user, as users typically have to manually maintain a stack of open elements.

Kiselyov realized that the SAX programming model could be made much simpler if the callbacks were formulated not as a linear fold across the features of the XML stream, but as a tree fold over the structure implicit in the XML.  In this way, the user has a very convenient, functional-style interface that can still generate optimal parsers.

The xml->sxml interface from the (sxml simple) module is a DOM-style parser built using SSAX, though it returns SXML instead of DOM objects.

Implementation
..............

(sxml ssax) is a package of low-to-high level lexing and parsing procedures that can be combined to yield a SAX, a DOM, a validating parser, or a parser intended for a particular document type.  The procedures in the package can be used separately to tokenize or parse various pieces of XML documents.  The package supports XML Namespaces, internal and external parsed entities, user-controlled handling of whitespace, and validation.  This module therefore is intended to be a framework, a set of ``Lego blocks'' you can use to build a parser following any discipline and performing validation to any degree.  As an example of the parser construction, the source file includes a semi-validating SXML parser.

SSAX has a ``sequential'' feel of SAX yet a ``functional style'' of DOM. Like a SAX parser, the framework scans the document only once and permits incremental processing.  An application that handles document elements in order can run as efficiently as possible.  Unlike a SAX parser, the framework does not require an application register stateful callbacks and surrender control to the parser.  Rather, it is the application that can drive the framework -- calling its functions to get the current lexical or syntax element.  These functions do not maintain or mutate any state save the input port.  Therefore, the framework permits parsing of XML in a pure functional style, with the input port being a monad (or a linear, read-once parameter).

Besides the PORT, there is another monad -- SEED.  Most of the middle- and high-level parsers are single-threaded through the SEED.  The functions of this framework do not process or affect the SEED in any way: they simply pass it around as an instance of an opaque datatype.  User functions, on the other hand, can use the seed to maintain user's state, to accumulate parsing results, etc.  A user can freely mix their own functions with those of the framework.  On the other hand, the user may wish to instantiate a high-level parser: SSAX:make-elem-parser or SSAX:make-parser.  In the latter case, the user must provide functions of specific signatures, which are called at predictable moments during the parsing: to handle character data, element data, or processing instructions (PI).  The functions are always given the SEED, among other parameters, and must return the new SEED.

From a functional point of view, XML parsing is a combined pre-post-order traversal of a ``tree'' that is the XML document itself. This down-and-up traversal tells the user about an element when its start tag is encountered.  The user is notified about the element once more, after all element's children have been handled.  The process of XML parsing therefore is a fold over the raw XML document.  Unlike a fold over trees defined in [1], the parser is necessarily single-threaded -- obviously as elements in a text XML document are laid down sequentially.  The parser therefore is a tree fold that has been transformed to accept an accumulating parameter [1,2].

Formally, the denotational semantics of the parser can be expressed as

      parser:: (Start-tag -> Seed -> Seed) ->
     	   (Start-tag -> Seed -> Seed -> Seed) ->
     	   (Char-Data -> Seed -> Seed) ->
     	   XML-text-fragment -> Seed -> Seed
      parser fdown fup fchar "<elem attrs> content </elem>" seed
       = fup "<elem attrs>" seed
     	(parser fdown fup fchar "content" (fdown "<elem attrs>" seed))

      parser fdown fup fchar "char-data content" seed
       = parser fdown fup fchar "content" (fchar "char-data" seed)

      parser fdown fup fchar "elem-content content" seed
       = parser fdown fup fchar "content" (
     	parser fdown fup fchar "elem-content" seed)

Compare the last two equations with the left fold

      fold-left kons elem:list seed = fold-left kons list (kons elem seed)

The real parser created by SSAX:make-parser is slightly more complicated, to account for processing instructions, entity references, namespaces, processing of document type declaration, etc.

The XML standard document referred to in this module is http://www.w3.org/TR/1998/REC-xml-19980210.html

The present file also defines a procedure that parses the text of an XML document or of a separate element into SXML, an S-expression-based model of an XML Information Set.  SXML is also an Abstract Syntax Tree of an XML document.  SXML is similar but not identical to DOM; SXML is particularly suitable for Scheme-based XML/HTML authoring, SXPath queries, and tree transformations.  See SXML.html for more details. SXML is a term implementation of evaluation of the XML document [3]. The other implementation is context-passing.

The present frameworks fully supports the XML Namespaces Recommendation: http://www.w3.org/TR/REC-xml-names/.

Other links:

[1]
     Jeremy Gibbons, Geraint Jones, "The Under-appreciated Unfold," Proc. ICFP'98, 1998, pp. 273-279.

[2]
     Richard S. Bird, The promotion and accumulation strategies in transformational programming, ACM Trans. Progr. Lang. Systems, 6(4):487-504, October 1984.

[3]
     Ralf Hinze, "Deriving Backtracking Monad Transformers," Functional Pearl. Proc ICFP'00, pp. 186-197.

Usage
.....

 -- Scheme Procedure: current-ssax-error-port

 -- Scheme Procedure: with-ssax-error-to-port port thunk

 -- Scheme Procedure: xml-token? _
      -- Scheme Procedure: pair? x
          Return `#t' if X is a pair; otherwise return `#f'.

 -- Scheme Syntax: xml-token-kind token

 -- Scheme Syntax: xml-token-head token

 -- Scheme Procedure: make-empty-attlist

 -- Scheme Procedure: attlist-add attlist name-value

 -- Scheme Procedure: attlist-null? x
     Return #t if X is the empty list, else #f.

 -- Scheme Procedure: attlist-remove-top attlist

 -- Scheme Procedure: attlist->alist attlist

 -- Scheme Procedure: attlist-fold kons knil lis1

 -- Scheme Procedure: define-parsed-entity! entity str
     Define a new parsed entity.  ENTITY should be a symbol.

     Instances of &ENTITY; in XML text will be replaced with the string STR, which will then be parsed.

 -- Scheme Procedure: reset-parsed-entity-definitions!
     Restore the set of parsed entity definitions to its initial state.

 -- Scheme Procedure: ssax:uri-string->symbol uri-str

 -- Scheme Procedure: ssax:skip-internal-dtd port

 -- Scheme Procedure: ssax:read-pi-body-as-string port

 -- Scheme Procedure: ssax:reverse-collect-str-drop-ws fragments

 -- Scheme Procedure: ssax:read-markup-token port

 -- Scheme Procedure: ssax:read-cdata-body port str-handler seed

 -- Scheme Procedure: ssax:read-char-ref port

 -- Scheme Procedure: ssax:read-attributes port entities

 -- Scheme Procedure: ssax:complete-start-tag tag-head port elems entities namespaces

 -- Scheme Procedure: ssax:read-external-id port

 -- Scheme Procedure: ssax:read-char-data port expect-eof? str-handler seed

 -- Scheme Procedure: ssax:xml->sxml port namespace-prefix-assig

 -- Scheme Syntax: ssax:make-parser . kw-val-pairs

 -- Scheme Syntax: ssax:make-pi-parser orig-handlers

 -- Scheme Syntax: ssax:make-elem-parser my-new-level-seed my-finish-element my-char-data-handler my-pi-handlers

Transforming SXML
-----------------

Overview
........

SXML expression tree transformers
=================================

Pre-Post-order traversal of a tree and creation of a new tree
-------------------------------------------------------------

     pre-post-order:: <tree> x <bindings> -> <new-tree>

where

      <bindings> ::= (<binding> ...)
      <binding> ::= (<trigger-symbol> *preorder* . <handler>) |
                    (<trigger-symbol> *macro* . <handler>) |
     		(<trigger-symbol> <new-bindings> . <handler>) |
     		(<trigger-symbol> . <handler>)
      <trigger-symbol> ::= XMLname | *text* | *default*
      <handler> :: <trigger-symbol> x [<tree>] -> <new-tree>

The pre-post-order function visits the nodes and nodelists pre-post-order (depth-first).  For each <Node> of the form (NAME <Node> ...), it looks up an association with the given NAME among its <BINDINGS>.  If failed, pre-post-order tries to locate a *default* binding.  It's an error if the latter attempt fails as well.  Having found a binding, the pre-post-order function first checks to see if the binding is of the form

     	(<trigger-symbol> *preorder* . <handler>)

If it is, the handler is 'applied' to the current node.  Otherwise, the pre-post-order function first calls itself recursively for each child of the current node, with <NEW-BINDINGS> prepended to the <BINDINGS> in effect.  The result of these calls is passed to the <HANDLER> (along with the head of the current <NODE>).  To be more precise, the handler is _applied_ to the head of the current node and its processed children.  The result of the handler, which should also be a <tree>, replaces the current <NODE>.  If the current <NODE> is a text string or other atom, a special binding with a symbol *text* is looked up.

A binding can also be of a form

     	(<trigger-symbol> *macro* . <handler>)

This is equivalent to *preorder* described above.  However, the result is re-processed again, with the current stylesheet.

Usage
.....

 -- Scheme Procedure: SRV:send-reply . fragments
     Output the FRAGMENTS to the current output port.

     The fragments are a list of strings, characters, numbers, thunks, #f, #t -- and other fragments.  The function traverses the tree depth-first, writes out strings and characters, executes thunks, and ignores #f and '().  The function returns #t if anything was written at all; otherwise the result is #f If #t occurs among the fragments, it is not written out but causes the result of SRV:send-reply to be #t.

 -- Scheme Procedure: foldts fdown fup fhere seed tree

 -- Scheme Procedure: post-order tree bindings

 -- Scheme Procedure: pre-post-order tree bindings

 -- Scheme Procedure: replace-range beg-pred end-pred forest

SXML Tree Fold
--------------

Overview
........

(sxml fold) defines a number of variants of the fold algorithm for use in transforming SXML trees.  Additionally it defines the layout operator, fold-layout, which might be described as a context-passing variant of SSAX's pre-post-order.

Usage
.....

 -- Scheme Procedure: foldt fup fhere tree
     The standard multithreaded tree fold.

     FUP is of type [a] -> a. FHERE is of type object -> a.

 -- Scheme Procedure: foldts fdown fup fhere seed tree
     The single-threaded tree fold originally defined in SSAX.  See SSAX, for more information.

 -- Scheme Procedure: foldts* fdown fup fhere seed tree
     A variant of foldts that allows pre-order tree rewrites.  Originally defined in Andy Wingo's 2007 paper, Applications of fold to XML transformation.

 -- Scheme Procedure: fold-values proc list . seeds
     A variant of fold that allows multi-valued seeds.  Note that the order of the arguments differs from that of fold.  See SRFI-1 Fold and Map.

 -- Scheme Procedure: foldts*-values fdown fup fhere tree . seeds
     A variant of foldts* that allows multi-valued seeds.  Originally defined in Andy Wingo's 2007 paper, Applications of fold to XML transformation.

 -- Scheme Procedure: fold-layout tree bindings params layout stylesheet
     A traversal combinator in the spirit of pre-post-order. See Transforming SXML.

     fold-layout was originally presented in Andy Wingo's 2007 paper, Applications of fold to XML transformation.

          bindings := (<binding>...)
          binding  := (<tag> <handler-pair>...)
                    | (*default* . <post-handler>)
                    | (*text* . <text-handler>)
          tag      := <symbol>
          handler-pair := (pre-layout . <pre-layout-handler>)
                    | (post . <post-handler>)
                    | (bindings . <bindings>)
                    | (pre . <pre-handler>)
                    | (macro . <macro-handler>)

     pre-layout-handler
          A function of three arguments:

          kids
               the kids of the current node, before traversal

          params
               the params of the current node

          layout
               the layout coming into this node

          PRE-LAYOUT-HANDLER is expected to use this information to return a layout to pass to the kids.  The default implementation returns the layout given in the arguments.

     post-handler
          A function of five arguments:

          tag
               the current tag being processed

          params
               the params of the current node

          layout
               the layout coming into the current node, before any kids were processed

          klayout
               the layout after processing all of the children

          kids
               the already-processed child nodes

          POST-HANDLER should return two values, the layout to pass to the next node and the final tree.

     text-handler
          TEXT-HANDLER is a function of three arguments:

          text
               the string

          params
               the current params

          layout
               the current layout

          TEXT-HANDLER should return two values, the layout to pass to the next node and the value to which the string should transform.

SXPath
------

Overview
........

SXPath: SXML Query Language
===========================

SXPath is a query language for SXML, an instance of XML Information set (Infoset) in the form of s-expressions.  See (sxml ssax) for the definition of SXML and more details.  SXPath is also a translation into Scheme of an XML Path Language, XPath (http://www.w3.org/TR/xpath). XPath and SXPath describe means of selecting a set of Infoset's items or their properties.

To facilitate queries, XPath maps the XML Infoset into an explicit tree, and introduces important notions of a location path and a current, context node.  A location path denotes a selection of a set of nodes relative to a context node.  Any XPath tree has a distinguished, root node -- which serves as the context node for absolute location paths. Location path is recursively defined as a location step joined with a location path.  A location step is a simple query of the database relative to a context node.  A step may include expressions that further filter the selected set.  Each node in the resulting set is used as a context node for the adjoining location path.  The result of the step is a union of the sets returned by the latter location paths.

The SXML representation of the XML Infoset (see SSAX.scm) is rather suitable for querying as it is.  Bowing to the XPath specification, we will refer to SXML information items as 'Nodes':

      	<Node> ::= <Element> | <attributes-coll> | <attrib>
      		   | "text string" | <PI>

This production can also be described as

     	<Node> ::= (name . <Nodeset>) | "text string"

An (ordered) set of nodes is just a list of the constituent nodes:

      	<Nodeset> ::= (<Node> ...)

Nodesets, and Nodes other than text strings are both lists.  A <Nodeset> however is either an empty list, or a list whose head is not a symbol.  A symbol at the head of a node is either an XML name (in which case it's a tag of an XML element), or an administrative name such as '@'.  This uniform list representation makes processing rather simple and elegant, while avoiding confusion.  The multi-branch tree structure formed by the mutually-recursive datatypes <Node> and <Nodeset> lends itself well to processing by functional languages.

A location path is in fact a composite query over an XPath tree or its branch.  A singe step is a combination of a projection, selection or a transitive closure.  Multiple steps are combined via join and union operations.  This insight allows us to elegantly implement XPath as a sequence of projection and filtering primitives -- converters -- joined by combinators.  Each converter takes a node and returns a nodeset which is the result of the corresponding query relative to that node.  A converter can also be called on a set of nodes.  In that case it returns a union of the corresponding queries over each node in the set. The union is easily implemented as a list append operation as all nodes in a SXML tree are considered distinct, by XPath conventions.  We also preserve the order of the members in the union.  Query combinators are high-order functions: they take converter(s) (which is a Node|Nodeset -> Nodeset function) and compose or otherwise combine them.  We will be concerned with only relative location paths [XPath]: an absolute location path is a relative path applied to the root node.

Similarly to XPath, SXPath defines full and abbreviated notations for location paths.  In both cases, the abbreviated notation can be mechanically expanded into the full form by simple rewriting rules.  In the case of SXPath the corresponding rules are given in the documentation of the sxpath procedure. See SXPath procedure documentation.

The regression test suite at the end of the file SXPATH-old.scm shows a representative sample of SXPaths in both notations, juxtaposed with the corresponding XPath expressions.  Most of the samples are borrowed literally from the XPath specification.

Much of the following material is taken from the SXPath sources by Oleg Kiselyov et al.

Basic Converters and Applicators
................................

A converter is a function mapping a nodeset (or a single node) to another nodeset.  Its type can be represented like this:

     type Converter = Node|Nodeset -> Nodeset

A converter can also play the role of a predicate: in that case, if a converter, applied to a node or a nodeset, yields a non-empty nodeset, the converter-predicate is deemed satisfied.  Likewise, an empty nodeset is equivalent to #f in denoting failure.

 -- Scheme Procedure: nodeset? x
     Return #t if X is a nodeset.

 -- Scheme Procedure: node-typeof? crit
     This function implements a 'Node test' as defined in Sec. 2.3 of the XPath document.  A node test is one of the components of a location step.  It is also a converter-predicate in SXPath.

     The function node-typeof? takes a type criterion and returns a function, which, when applied to a node, will tell if the node satisfies the test.

     The criterion CRIT is a symbol, one of the following:

     id
          tests if the node has the right name (id)

     @
          tests if the node is an <attributes-coll>

     *
          tests if the node is an <Element>

     *text*
          tests if the node is a text node

     *PI*
          tests if the node is a PI (processing instruction) node

     *any*
          #t for any type of node

 -- Scheme Procedure: node-eq? other
     A curried equivalence converter predicate that takes a node OTHER and returns a function that takes another node.  The two nodes are compared using eq?.

 -- Scheme Procedure: node-equal? other
     A curried equivalence converter predicate that takes a node OTHER and returns a function that takes another node.  The two nodes are compared using equal?.

 -- Scheme Procedure: node-pos n
     Select the N'th element of a nodeset and return as a singular nodeset.  If the N'th element does not exist, return an empty nodeset.  If N is a negative number the node is picked from the tail of the list.

          ((node-pos 1) nodeset)  ; return the the head of the nodeset (if exists)
          ((node-pos 2) nodeset)  ; return the node after that (if exists)
          ((node-pos -1) nodeset) ; selects the last node of a non-empty nodeset
          ((node-pos -2) nodeset) ; selects the last but one node, if exists.

 -- Scheme Procedure: filter pred?
     A filter applicator, which introduces a filtering context.  The argument converter PRED? is considered a predicate, with either #f or nil meaning failure.

 -- Scheme Procedure: take-until pred?

          take-until:: Converter -> Converter, or
          take-until:: Pred -> Node|Nodeset -> Nodeset

     Given a converter-predicate PRED? and a nodeset, apply the predicate to each element of the nodeset, until the predicate yields anything but #f or nil.  Return the elements of the input nodeset that have been processed until that moment (that is, which fail the predicate).

     take-until is a variation of the filter above: take-until passes elements of an ordered input set up to (but not including) the first element that satisfies the predicate.  The nodeset returned by ((take-until (not pred)) nset) is a subset -- to be more precise, a prefix -- of the nodeset returned by ((filter pred) nset).

 -- Scheme Procedure: take-after pred?

          take-after:: Converter -> Converter, or
          take-after:: Pred -> Node|Nodeset -> Nodeset

     Given a converter-predicate PRED? and a nodeset, apply the predicate to each element of the nodeset, until the predicate yields anything but #f or nil.  Return the elements of the input nodeset that have not been processed: that is, return the elements of the input nodeset that follow the first element that satisfied the predicate.

     take-after along with take-until partition an input nodeset into three parts: the first element that satisfies a predicate, all preceding elements and all following elements.

 -- Scheme Procedure: map-union proc lst
     Apply PROC to each element of LST and return the list of results. If PROC returns a nodeset, splice it into the result

     From another point of view, map-union is a function Converter->Converter, which places an argument-converter in a joining context.

 -- Scheme Procedure: node-reverse node-or-nodeset

          node-reverse :: Converter, or
          node-reverse:: Node|Nodeset -> Nodeset

     Reverses the order of nodes in the nodeset.  This basic converter is needed to implement a reverse document order (see the XPath Recommendation).

 -- Scheme Procedure: node-trace title

          node-trace:: String -> Converter

     (node-trace title) is an identity converter.  In addition it prints out the node or nodeset it is applied to, prefixed with the TITLE.  This converter is very useful for debugging.

Converter Combinators
.....................

Combinators are higher-order functions that transmogrify a converter or glue a sequence of converters into a single, non-trivial converter.  The goal is to arrive at converters that correspond to XPath location paths.

From a different point of view, a combinator is a fixed, named pattern of applying converters.  Given below is a complete set of such patterns that together implement XPath location path specification. As it turns out, all these combinators can be built from a small number of basic blocks: regular functional composition, map-union and filter applicators, and the nodeset union.

 -- Scheme Procedure: select-kids test-pred?
     select-kids takes a converter (or a predicate) as an argument and returns another converter.  The resulting converter applied to a nodeset returns an ordered subset of its children that satisfy the predicate TEST-PRED?.

 -- Scheme Procedure: node-self pred?
     Similar to select-kids except that the predicate PRED? is applied to the node itself rather than to its children.  The resulting nodeset will contain either one component, or will be empty if the node failed the predicate.

 -- Scheme Procedure: node-join . selectors

          node-join:: [LocPath] -> Node|Nodeset -> Nodeset, or
          node-join:: [Converter] -> Converter

     Join the sequence of location steps or paths as described above.

 -- Scheme Procedure: node-reduce . converters

          node-reduce:: [LocPath] -> Node|Nodeset -> Nodeset, or
          node-reduce:: [Converter] -> Converter

     A regular functional composition of converters.  From a different point of view, ((apply node-reduce converters) nodeset) is equivalent to (foldl apply nodeset converters), i.e., folding, or reducing, a list of converters with the nodeset as a seed.

 -- Scheme Procedure: node-or . converters

          node-or:: [Converter] -> Converter

     This combinator applies all converters to a given node and produces the union of their results.  This combinator corresponds to a union (| operation) for XPath location paths.

 -- Scheme Procedure: node-closure test-pred?

          node-closure:: Converter -> Converter

     Select all descendants of a node that satisfy a converter-predicate TEST-PRED?.  This combinator is similar to select-kids but applies to grand... children as well.  This combinator implements the descendant:: XPath axis.  Conceptually, this combinator can be expressed as

          (define (node-closure f)
            (node-or
              (select-kids f)
              (node-reduce (select-kids (node-typeof? '*)) (node-closure f))))

     This definition, as written, looks somewhat like a fixpoint, and it will run forever.  It is obvious however that sooner or later (select-kids (node-typeof? '*)) will return an empty nodeset.  At this point further iterations will no longer affect the result and can be stopped.

 -- Scheme Procedure: node-parent rootnode

          node-parent:: RootNode -> Converter

     (node-parent rootnode) yields a converter that returns a parent of a node it is applied to.  If applied to a nodeset, it returns the list of parents of nodes in the nodeset.  The ROOTNODE does not have to be the root node of the whole SXML tree -- it may be a root node of a branch of interest.

     Given the notation of Philip Wadler's paper on semantics of XSLT,

       parent(x) = { y | y=subnode*(root), x=subnode(y) }

     Therefore, node-parent is not the fundamental converter: it can be expressed through the existing ones.  Yet node-parent is a rather convenient converter.  It corresponds to a parent:: axis of SXPath.  Note that the parent:: axis can be used with an attribute node as well.

 -- Scheme Procedure: sxpath path
     Evaluate an abbreviated SXPath.

          sxpath:: AbbrPath -> Converter, or
          sxpath:: AbbrPath -> Node|Nodeset -> Nodeset

     PATH is a list.  It is translated to the full SXPath according to the following rewriting rules:

          (sxpath '())
          => (node-join)

          (sxpath '(path-component ...))
          => (node-join (sxpath1 path-component) (sxpath '(...)))

          (sxpath1 '//)
          => (node-or
             (node-self (node-typeof? '*any*))
             (node-closure (node-typeof? '*any*)))

          (sxpath1 '(equal? x))
          => (select-kids (node-equal? x))

          (sxpath1 '(eq? x))
          => (select-kids (node-eq? x))

          (sxpath1 ?symbol)
          => (select-kids (node-typeof? ?symbol)

          (sxpath1 procedure)
          => procedure

          (sxpath1 '(?symbol ...))
          => (sxpath1 '((?symbol) ...))

          (sxpath1 '(path reducer ...))
          => (node-reduce (sxpath path) (sxpathr reducer) ...)

          (sxpathr number)
          => (node-pos number)

          (sxpathr path-filter)
          => (filter (sxpath path-filter))

(sxml ssax input-parse)
-----------------------

Overview
........

A simple lexer.

The procedures in this module surprisingly often suffice to parse an input stream.  They either skip, or build and return tokens, according to inclusion or delimiting semantics.  The list of characters to expect, include, or to break at may vary from one invocation of a function to another.  This allows the functions to easily parse even context-sensitive languages.

EOF is generally frowned on, and thrown up upon if encountered. Exceptions are mentioned specifically.  The list of expected characters (characters to skip until, or break-characters) may include an EOF "character", which is to be coded as the symbol, *eof*.

The input stream to parse is specified as a port, which is usually the last (and optional) argument.  It defaults to the current input port if omitted.

If the parser encounters an error, it will throw an exception to the key parser-error.  The arguments will be of the form (PORT MESSAGE SPECIALISING-MSG*).

The first argument is a port, which typically points to the offending character or its neighborhood.  You can then use port-column and port-line to query the current position.  MESSAGE is the description of the error.  Other arguments supply more details about the problem.

Usage
.....

 -- Scheme Procedure: peek-next-char [port]

 -- Scheme Procedure: assert-curr-char expected-chars comment [port]

 -- Scheme Procedure: skip-until arg [port]

 -- Scheme Procedure: skip-while skip-chars [port]

 -- Scheme Procedure: next-token prefix-skipped-chars break-chars [comment] [port]

 -- Scheme Procedure: next-token-of incl-list/pred [port]

 -- Scheme Procedure: read-text-line [port]

 -- Scheme Procedure: read-string n [port]

 -- Scheme Procedure: find-string-from-port? _ _ . _
     Looks for STR in <INPUT-PORT>, optionally within the first MAX-NO-CHAR characters.

(sxml apply-templates)
----------------------

Overview
........

Pre-order traversal of a tree and creation of a new tree:

     	apply-templates:: tree x <templates> -> <new-tree>

where

      <templates> ::= (<template> ...)
      <template>  ::= (<node-test> <node-test> ... <node-test> . <handler>)
      <node-test> ::= an argument to node-typeof? above
      <handler>   ::= <tree> -> <new-tree>

This procedure does a normal, pre-order traversal of an SXML tree.  It walks the tree, checking at each node against the list of matching templates.

If the match is found (which must be unique, i.e., unambiguous), the corresponding handler is invoked and given the current node as an argument.  The result from the handler, which must be a <tree>, takes place of the current node in the resulting tree.  The name of the function is not accidental: it resembles rather closely an apply-templates function of XSLT.

Usage
.....

 -- Scheme Procedure: apply-templates tree templates